原理：

文件夹隐藏属性为灰色，无法修改的解决方案

今天,莫名其妙地中毒了.

隐藏的文件夹可以打开,但隐藏的属性为灰色,无法更改.这应该是autorun病毒引起的,所以大家使用U盘时,一定要小心为上!,现在的病毒实在是太多了.

解决方法:

1:"开始"-"运行"输入"cmd"

2:进入出问题的盘 接输入如"F:"回车
其中.入文件夹用cd 如cd changefile (changefile为文件夹名字)

3:attrib /s /d -s -h

每个盘重复步骤2,3即可.

以下是attrib的原理:

现在很多通过u盘进行传播的病毒又新出了这么一个特性：就是感染之后你的文件夹都被隐藏了，你想通过改文件属性改出来的时候却发现属性里面的
隐藏项是灰色的！！！

那怎么办呢?下面就是解决这个问题的办法

接下来是相关的命令知识

在cmd中可以用ATTRIB [+R | -R] [+A | -A ] [+S | -S] [+H | -H]

[[drive:] [path] filename] [/S [ /D]]

+ 设置属性。

- 清除属性。

R 只读文件属性。

A 存档文件属性。

S 系统文件属性。

H 隐藏文件属性。

[drive:][path][filename]

指定要处理的文件属性。

/S 处理当前文件夹及其子文件夹中的匹配文件。

/D 也处理文件夹。

一下是具体点的解决方法：

ATTRIB -S -H X（盘符名）:文件名

其它方案:

attrib Drive:\Path\"File Name" -s -h 或者 attrib "Drive:\Path\File Name" -s -h

考虑到一些网友的U盘文件夹比较多，又对此方法做出优化：

attrib "[Drive:\Path\*]" -s -h /s /d （处理此目录下的所有文件和文件夹）或者打开命令提示符CMD，进入需要处理的目录输入：

attrib *.* -s -h /s /d

下面给处一段实用的批处理：

@echo off
setlocal enabledelayedexpansion
title 修改系统属性和隐藏属性
color f0
mode con: cols=50 lines=25
if "%~1"=="" (
echo 你没有拖入任何磁盘或文件或文件夹
echo 请把要处理的磁盘或文件或文件夹拖到批处理文件图标
echo 不要双击启动批处理
pause
)
:loop
cls
if "%~1"=="" goto :eof
if not exist "%~1" (echo 路径不存在)&pause&shift&goto loop
echo 当前处理的磁盘或文件或文件夹:
echo %~1
echo.
echo 请选择要进行的操作，然后按回车
echo.
echo 加系统和隐藏属性……………………………1
echo 减系统和隐藏属性……………………………2
echo 不处理…………………………………………3
echo.
set /p "c1=选择 (1,2,3) (不输入为!c1!,默认为2):"
if "!c1!"=="1" (set "d=+") else if "!c1!"=="3" (pause&shift&goto loop) else set "d=-"
set "a=%~a1"
if /i "!a:~0,1!"=="d" (
echo.
echo 这是一个文件夹，请选择要进行的操作，然后按回车
echo.
echo 只对该文件夹本身……………………………1
echo 只对该文件夹中的文件夹和文件……………2
echo 对该目录下的一切的文件夹和文件…………3
echo.
set /p "c2=选择 (1,2,3) (不输入为!c2!,默认为1):"
if "!c2!"=="2" (
pushd "%~1"
for /f "delims=" %%i in ('dir /a /b "%~1"') do attrib.exe !d!s !d!h "%%i"
popd
) else if "!c2!"=="3" (
for /f "delims=" %%i in ('dir /a /b /s "%~1"') do attrib.exe !d!s !d!h "%%i"
) else (
attrib.exe !d!s !d!h "%~1"
)
) else (
attrib.exe !d!s !d!h "%~1"
)
pause&shift&goto loop

提供下载该批处理。